#!/usr/bin/perl
#%# family=auto
#%# capabilities=autoconf suggest
#
#  This is a munin plugin to monitor java instances (old generation memory, garbage collection stats etc)
#  It uses jps and jstat to fetch information. These tools work reliably with jdk6 and work with jdk1.5
#  Author: Oles Hnatkevych <don_oles@able.com.ua>
#
# Parameters:
#
#   config
#   autoconf
#   suggest
#
# Configuration variables
#
#   Global environment variables:
#
#   JVMS - list of instances to monitor, example: env.JVMS confluence jira fisheye
#   JAVA_HOME - Override location of JDK, example: env.JAVA_HOME /usr/java/jdk1.6.0_06
#   WGET - path to wget binary, example: env.WGET /usr/bin/wget
#   if WGET is defined, then it will be used to trigger a script that performs garbage collection
#
#   Environment variables per instance:
#   
#   JVM_<instance>_PID - path to file that contains PID of running java process to monitor 
#   JVM_<instance>_USER - username to swith to before runnint jstat and jps
#   JVM_<instance>_JPSRE - regular expression (substring) to filter jps output to find pid of target jvm
#   JVM_<instance>_JAVAHOME - if defined, overrides JAVA_HOME for that instance
#   JVM_<instance>_GCURL - if defined along with WGET, wget will trigger fetching of that URL (to force garbage collection)
#  
#   Either PID or JPSRE must be defined to find PID
#   To force garbage collection you can create a file gc.jsp with just one row and put into ROOT directory of Apache Tomcat
#   <% System.gc(); %>
#   
#   Example of configuration in plugins-conf.d/jvm2
#
# [jvm2_*]
# user root
# env.JVMS confluence jira
# env.JAVA_HOME /usr/java/jdk1.6.0_06
# env.WGET /usr/bin/wget
#
# env.JVM_confluence_PID /home/confluence/catalina-base/temp/catalina.pid
# env.JVM_confluence_USER confluence
# env.JVM_confluence_GCURL http://localhost:19180/gc.jsp
# # env.JVM_confluence_JPSRE /home/confluence/catalina-base/
# # env.JVM_confluence_JAVAHOME /usr/java/jdk1.6.0_06
#
# env.JVM_jira_PID /home/jira/catalina-base/temp/catalina.pid
# env.JVM_jira_USER jira
# env.JVM_jira_GCURL http://localhost:19280/gc.jsp
# # env.JVM_jira_JPSRE /home/jira/catalina-base/
# # env.JVM_jira_JAVAHOME /usr/java/jdk1.6.0_06
#
#

use strict;
no strict "refs";

my $JVMS = $ENV{JVMS};

my $JAVA_HOME = $ENV{JAVA_HOME};
my $WGET = $ENV{WGET};
my $JVM_PIDFILE;
my $GC_URL;
my $JVM_USER='root';
my $JPS_RE;
my $COMMAND  = "jps -lv";
my $COMMAND2 = "jstat";

my $jvm_pid;
my @GC=();
my @GCCAP=();
my $arg = shift;
my $testname;
my $jvmname;


#-----------------------------------------------

if ($arg eq 'autoconf') {
  if ($JVMS ne "" )
  {
    print "yes\n";
    exit 0;
  }
  else
  {
    print "no\n";
    exit 1;
  }
}

#-----------------------------------------------

if ($arg eq "suggest") {
    foreach my $jvm (split(/\s+/,$JVMS)) {
        print "${jvm}_gcold\n";
        print "${jvm}_gcoldpc\n";
        print "${jvm}_gctime\n";
        print "${jvm}_gccap\n";
    }
    exit;
}


#-----------------------------------------------

if ($0 =~ /jvm2_(\w+)_(gcold|gctime|gccap|gcoldpc)$/) {
  $jvmname = $1;
  $testname = $2;
  if ($ENV{"JVM_${jvmname}_PID"})      { $JVM_PIDFILE = $ENV{"JVM_${jvmname}_PID"}; }
  if ($ENV{"JVM_${jvmname}_JAVAHOME"}) { $JAVA_HOME = $ENV{"JVM_${jvmname}_JAVAHOME"};   }
  if ($ENV{"JVM_${jvmname}_JPSRE"})    { $JPS_RE = $ENV{"JVM_${jvmname}_JPSRE"};   }
  if ($ENV{"JVM_${jvmname}_USER"})     { $JVM_USER = $ENV{"JVM_${jvmname}_USER"};   }
  if ($ENV{"JVM_${jvmname}_USER"})     { $JVM_USER = $ENV{"JVM_${jvmname}_USER"};   }
  if ($ENV{"JVM_${jvmname}_GCURL"})    { $GC_URL = $ENV{"JVM_${jvmname}_GCURL"};   }
  if ($JPS_RE eq "" && $JVM_PIDFILE eq "") {
     print STDERR "No definitions for $jvmname!\n";
     exit 1;
  }
} else {
   print STDERR "Not proper script name: $0\n";
   exit 1;
}

#-----------------------------------------------

if ($arg eq 'config') {
    my $funcname = "print_config_${testname}";
    if (defined &$funcname)
    {
        &$funcname();
        exit;
    }
    else
    {
        print STDERR "No config for $testname was defined\n";
        exit 1;
    }
    exit;
}

#-----------------------------------------------

$jvm_pid = get_jvm_pid();
get_status();

if ($testname eq "gcold")
{
    print "oc.value ".(int ($GC[6] * 1024))."\n";
    print "ou.value ".(int ($GC[7] * 1024))."\n";
}
elsif ($testname eq "gcoldpc")
{
    print "oldpc.value ".(int (100 * $GC[7] / $GC[6]))."\n";
}
elsif ($testname eq "gctime")
{
    print "ygct.value ".(int (@GC[11] * 1000))."\n";
    print "fgct.value ".(int (@GC[13] * 1000))."\n";
    print "gct.value " .(int (@GC[14] * 1000))."\n";
}
elsif ($testname eq "gccap")
{
    print "ec.value ". (int (@GCCAP[5]  * 1024))."\n";
    print "s0c.value ".(int (@GCCAP[3]  * 1024))."\n";
    print "s1c.value ".(int (@GCCAP[4]  * 1024))."\n";
    print "pc.value ". (int (@GCCAP[13] * 1024))."\n";
}
else
{
    print STDERR "No processing for test $testname\n";
    exit 1;
}


#-----------------------------------------------

sub print_config_gcold {
    print <<EOF;
graph_title JVM old generation memory ($jvmname)
graph_args -l 0 --base 1024
graph_vlabel KBytes
graph_category java
oc.label capacity
oc.min 0
oc.type GAUGE
oc.draw AREA
ou.label used
ou.min 0
ou.type GAUGE
ou.draw AREA
EOF
}

sub print_config_gcoldpc {
    print <<EOF;
graph_title JVM old generation use percent ($jvmname)
graph_args -l 0 
graph_vlabel %
graph_category java
oldpc.label percents
oldpc.min 0
oldpc.type GAUGE
oldpc.draw AREA
EOF
}

sub print_config_gctime {
    print <<EOF;
graph_title JVM garbage collection time ($jvmname)
graph_args -l 0
graph_vlabel msec / 5min
graph_category java
ygct.label young collection time
ygct.min 0
ygct.type DERIVE
ygct.draw LINE1
ygct.cdef ygct,900000,/
fgct.label full collection time
fgct.min 0
fgct.type DERIVE
fgct.draw LINE1
fgct.cdef fgct,900000,/
gct.label total collection time
gct.min 0
gct.type DERIVE
gct.draw LINE1
gct.cdef gct,900000,/
EOF
}

sub print_config_gccap {
    print <<EOF;
graph_title JVM generation capacities ($jvmname)
graph_args -l 0
graph_vlabel KBytes
graph_category java
ec.label eden
ec.min 0
ec.type GAUGE
ec.draw LINE1
pc.label permanent
pc.min 0
pc.type GAUGE
pc.draw LINE1
s0c.label survivor 0
s0c.min 0
s0c.type GAUGE
s0c.draw LINE1
s1c.label survivor 1
s1c.min 0
s1c.type GAUGE
s1c.draw LINE1
EOF
}

sub get_status {
    my $cmd;

    if ($WGET ne "" && $GC_URL ne "") {
        $cmd = "$WGET -O /dev/null $GC_URL 2>/dev/null";
        # print STDERR "jc: $cmd\n";
        system $cmd;
    }

    $cmd =  "/bin/su -m $JVM_USER -c \"$JAVA_HOME/bin/$COMMAND2 -gc $jvm_pid\" |";
    open(SERVICE, $cmd) or die("Could not execute $cmd: $!");
    <SERVICE>; # first line is legend
    @GC = split /\s+/, <SERVICE>;
    close(SERVICE);

    $cmd =  "/bin/su -m $JVM_USER -c \"$JAVA_HOME/bin/$COMMAND2 -gccapacity $jvm_pid\" |";
    open(SERVICE, $cmd) or die("Could not execute $cmd: $!");
    <SERVICE>; # first line is legend
    @GCCAP = split /\s+/, <SERVICE>;
    close(SERVICE);
}


#-----------------------------------------------

sub get_jvm_pid
{
  my $pid = 0;

  if ($JVM_PIDFILE ne "") {
     $pid = `cat $JVM_PIDFILE`;
     $pid =~ /(\d+)/;
     $pid = $1;
     # print STDERR "pid by pidfile: $pid\n";
     return $pid;
     #--------------------------
  }

  my @jps = split(/\n/,`$JAVA_HOME/bin/$COMMAND`);
  foreach my $line (@jps)
  {
    next if ($line =~ /sun\.tools\.jps\.Jps/); # skip our jps itself
    if ($JPS_RE ne "") 
    {
      next unless ($line =~ /$JPS_RE/); 
    }
    next unless ($line =~ /^(\d+) (\S+)/);
    $pid = $1;
  }
  # print STDERR "pid by regexp: $pid\n";
  return $pid;
}